scripts/cog/BUILD.gn

# Copyright 2025 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/python/python_host_test.gni")

group("tests") {
  testonly = true
  deps = [
    ":logger_test($host_toolchain)",
    ":mock_fs_test($host_toolchain)",
    ":preflight_test($host_toolchain)",
    ":setup_cog_workspace_test($host_toolchain)",
    ":sync_workspace_test($host_toolchain)",
    ":util_test($host_toolchain)",
    ":workspace_test($host_toolchain)",
  ]
}

if (is_host) {
  common_sources = [
    "cartfs.py",
    "logger.py",
    "preflight.py",
    "setup_cog_workspace.py",
    "snapshotter.py",
    "sync_workspace.py",
    "tests/mock_fs.py",
    "util.py",
    "workspace.py",
  ]

  test_names = [
    "mock_fs",
    "setup_cog_workspace",
    "workspace",
    "logger",
    "sync_workspace",
    "util",
    "preflight",
  ]

  foreach(test_name, test_names) {
    python_host_test("${test_name}_test") {
      main_source = "tests/test_${test_name}.py"
      sources = common_sources
      libraries = [ "//third_party/parameterized" ]
    }
  }
}