build/dist/distribution_manifest_generated_file.gni

# Copyright 2025 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

template("distribution_manifest_generated_file") {
  # Gather metadata about runtime objects.
  generated_file(target_name) {
    forward_variables_from(invoker,
                           [
                             "applicable_licenses",
                             "deps",
                             "outputs",
                             "testonly",
                             "visibility",
                           ])

    # See //docs/concepts/build_system/internals/distribution_manifest.md
    # for the schema of `distribution_entries` and `distribution_entries_files`,
    # which correspond to "regular" and "file" entries, respectively.
    data_keys = [
      # A list of scopes describing files that may be added to runtime.
      "distribution_entries",

      # A list of scopes representing data files listing distributable objects.
      "distribution_entries_files",
    ]
    walk_keys = [ "distribution_entries_barrier" ]

    output_conversion = "json"
  }
}