# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_binary.gni")
import("//build/rust/rustc_test.gni")

rustc_binary("bin") {
  name = "inspect_rust_codelab_part_1"
  edition = "2021"
  with_unit_tests = true

  deps = [
    "//examples/diagnostics/inspect/codelab/fidl:fuchsia.examples.inspect_rust",

    # CODELAB: Include inspect dependency.
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:tracing",
  ]

  test_deps = [ "//src/lib/fidl/rust/fidl" ]

  sources = [
    "src/main.rs",
    "src/reverser.rs",
  ]
}

fuchsia_component("part_1") {
  manifest = "meta/part_1.cml"
  deps = [ ":bin" ]
}

rustc_test("integration_test") {
  name = "inspect_rust_codelab_part_1_integration_test"
  source_root = "tests/integration_test.rs"
  edition = "2021"

  deps = [
    "//examples/diagnostics/inspect/codelab/rust/testing:inspect-rust-codelab-testing",
    "//src/lib/fuchsia",
    "//third_party/rust_crates:anyhow",
  ]

  sources = [ "tests/integration_test.rs" ]
}