src/devices/serial/drivers/usb-cdc-acm/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/components.gni")
import("//build/drivers.gni")
import("//build/test.gni")

driver_bind_rules("cdc_acm_bind") {
  rules = "meta/cdc_acm.bind"
  bind_output = "usb-cdc-acm.bindbc"
  tests = "meta/bind_tests.json"
  deps = [
    "//src/devices/bind/fuchsia.usb",
    "//src/devices/bind/fuchsia.usb.comm",
  ]
}

fuchsia_cc_driver("usb-cdc-acm-driver") {
  legacy = true
  output_name = "usb-cdc-acm"
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  sources = [ "usb-cdc-acm.cc" ]
  deps = [
    ":cdc_acm_bind",
    "//sdk/banjo/fuchsia.hardware.usb:fuchsia.hardware.usb_banjo_cpp",
    "//sdk/banjo/fuchsia.hardware.usb.composite:fuchsia.hardware.usb.composite_banjo_cpp",
    "//sdk/fidl/fuchsia.hardware.serialimpl:fuchsia.hardware.serialimpl_cpp",
    "//sdk/lib/driver/outgoing/cpp",
    "//sdk/lib/stdcompat",
    "//src/devices/lib/driver",
    "//src/devices/lib/driver:driver_runtime",
    "//src/devices/usb/lib/usb",
    "//src/devices/usb/lib/usb:cdc",
    "//src/lib/ddk",
    "//src/lib/ddktl",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/sync",
    "//zircon/system/ulib/zx",
  ]
}

fuchsia_driver_component("usb-cdc-acm") {
  visibility = [
    ":*",
    "//src/devices/serial:drivers",
  ]
  info = "meta/usb-cdc-acm-info.json"
  component_name = "usb-cdc-acm"
  deps = [ ":usb-cdc-acm-driver" ]
  manifest = "meta/usb-cdc-acm.cml"
}

fuchsia_driver_package("package") {
  package_name = "usb-cdc-acm"
  driver_components = [ ":usb-cdc-acm" ]
}

driver_bind_rules("usb_cdc_acm_function_bind") {
  rules = "meta/usb_cdc_acm_function.bind"
  tests = "meta/function_bind_tests.json"
  deps = [
    "//src/devices/bind/fuchsia.usb",
    "//src/devices/bind/fuchsia.usb.comm",
  ]
}

fuchsia_cc_driver("fake-usb-cdc-acm-driver") {
  legacy = true
  output_name = "fake-usb-cdc-acm"
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  sources = [ "usb-cdc-acm-function.cc" ]
  deps = [
    ":usb_cdc_acm_function_bind",
    "//sdk/banjo/fuchsia.hardware.usb:fuchsia.hardware.usb_banjo_cpp",
    "//sdk/banjo/fuchsia.hardware.usb.composite:fuchsia.hardware.usb.composite_banjo_cpp",
    "//sdk/banjo/fuchsia.hardware.usb.function:fuchsia.hardware.usb.function_banjo_cpp",
    "//sdk/banjo/fuchsia.hardware.usb.request:fuchsia.hardware.usb.request_banjo_cpp",
    "//src/devices/lib/driver",
    "//src/devices/usb/lib/usb",
    "//src/devices/usb/lib/usb:cdc",
    "//src/devices/usb/lib/usb:hid",
    "//src/devices/usb/lib/usb:peripheral",
    "//src/lib/ddk",
    "//src/lib/ddktl",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/sync",
    "//zircon/system/ulib/zircon-internal",
  ]
}

fuchsia_driver_component("fake-usb-cdc-acm") {
  info = "meta/fake-usb-cdc-acm-info.json"
  component_name = "fake-usb-cdc-acm"
  deps = [ ":fake-usb-cdc-acm-driver" ]
  manifest = "meta/fake-usb-cdc-acm.cml"
}

test("usb-cdc-acm-integration") {
  output_name = "usb-cdc-acm-integration-test"
  sources = [ "usb-cdc-acm-test.cc" ]
  deps = [
    "//sdk/fidl/fuchsia.hardware.serial:fuchsia.hardware.serial_cpp",
    "//sdk/fidl/fuchsia.hardware.usb.peripheral:fuchsia.hardware.usb.peripheral_cpp",
    "//sdk/fidl/fuchsia.hardware.usb.virtual.bus:fuchsia.hardware.usb.virtual.bus_cpp",
    "//sdk/lib/component/incoming/cpp",
    "//sdk/lib/fdio",
    "//src/devices/usb/lib/usb",
    "//src/devices/usb/lib/usb:cdc",
    "//src/devices/usb/testing/usb-virtual-bus-launcher",
    "//src/lib/ddk",
    "//src/ui/input/lib/hid",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/fdio-caller",
    "//zircon/system/ulib/zx",
    "//zircon/system/ulib/zxtest",
  ]
}

fuchsia_unittest_package("usb-cdc-acm-integration-test") {
  deps = [
    ":fake-usb-cdc-acm",
    ":usb-cdc-acm",
    ":usb-cdc-acm-integration",
    "//src/devices/board/drivers/integration-test",
    "//src/devices/bus/drivers/platform",
    "//src/devices/serial/drivers/serial",
    "//src/devices/usb/drivers/usb-bus",
    "//src/devices/usb/drivers/usb-composite",
    "//src/devices/usb/drivers/usb-peripheral",
    "//src/devices/usb/drivers/usb-virtual-bus",
  ]

  # For 'Failed to get banjo protocol' from the compat shim.
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
}

group("tests") {
  testonly = true
  deps = [
    ":cdc_acm_bind_test",

    # TODO(b/317170136): Fix flakes and re-enable
    #":usb-cdc-acm-integration-test",
    ":usb_cdc_acm_function_bind_test",
  ]
}