# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/package.gni")
import("//build/rust/rustc_binary.gni")
import("//build/testing/environments.gni")

rustc_binary("bin") {
  name = "stash"
  with_unit_tests = true
  edition = "2018"

  deps = [
    "//garnet/public/lib/fidl/rust/fidl",
    "//garnet/public/rust/fuchsia-app",
    "//garnet/public/rust/fuchsia-async",
    "//garnet/public/rust/fuchsia-syslog",
    "//garnet/public/rust/fuchsia-zircon",
    "//garnet/public/rust/fuchsia-zircon/fuchsia-zircon-sys",
    "//sdk/fidl/fuchsia.stash:fuchsia.stash-rustc",
    "//third_party/rust_crates:byteorder",
    "//third_party/rust_crates:bytes",
    "//third_party/rust_crates:failure",
    "//third_party/rust_crates:futures-preview",
    "//third_party/rust_crates:parking_lot",
    "//third_party/rust_crates:tempfile",
    "//zircon/public/fidl/fuchsia-mem:fuchsia-mem-rustc",
  ]
}

package("stash") {
  deps = [
    ":bin",
  ]

  binary = "rust_crates/stash"

  meta = [
    {
      path = rebase_path("meta/stash.cmx")
      dest = "stash.cmx"
    },
    {
      path = rebase_path("meta/stash_secure.cmx")
      dest = "stash_secure.cmx"
    },
    {
      path = rebase_path("meta/stash_tests.cmx")
      dest = "stash_tests.cmx"
    },
  ]
}

package("stash_tests") {
  testonly = true

  deps = [
    ":bin",
  ]

  tests = [
    {
      name = "stash_bin_test"
      environments = basic_envs
    },
  ]
}