src/sys/component_manager/tests/storage/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/rust/rustc_binary.gni")
import("//build/rust/rustc_test.gni")
import("//src/sys/build/components.gni")

rustc_test("storage_integration_test_bin") {
  name = "storage_integration_test"
  edition = "2018"
  source_root = "integration_test.rs"
  deps = [
    "//garnet/lib/rust/io_util",
    "//sdk/fidl/fuchsia.io:fuchsia.io-rustc",
    "//sdk/fidl/fuchsia.sys2:fuchsia.sys2-rustc",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/syslog/rust:syslog",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//src/sys/component_manager/testing:test_utils_lib",
    "//src/sys/component_manager/tests/fidl:components-rustc",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:async-trait",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:lazy_static",
  ]

  sources = [ "integration_test.rs" ]
}

rustc_binary("storage_realm_coll_bin") {
  name = "storage_realm_coll"
  edition = "2018"
  source_root = "storage_realm_coll.rs"
  deps = [
    "//sdk/fidl/fuchsia.io:fuchsia.io-rustc",
    "//sdk/fidl/fuchsia.sys2:fuchsia.sys2-rustc",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//src/sys/component_manager/tests/fidl:components-rustc",
    "//third_party/rust_crates:anyhow",
  ]

  sources = [ "storage_realm_coll.rs" ]
}

rustc_binary("storage_user_bin") {
  name = "storage_user"
  edition = "2018"
  source_root = "storage_user.rs"
  deps = [
    "//garnet/lib/rust/io_util",
    "//sdk/fidl/fuchsia.io:fuchsia.io-rustc",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-runtime",
    "//src/lib/storage/vfs/rust:vfs",
    "//src/lib/syslog/rust:syslog",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//src/sys/lib/directory_broker",
    "//third_party/rust_crates:anyhow",
  ]

  sources = [ "storage_user.rs" ]
}

fuchsia_component("memfs") {
  deps = [ "//src/sys/component_manager/tests/memfs" ]
  manifest = "meta/memfs.cml"
}

fuchsia_component("storage_user") {
  deps = [ ":storage_user_bin" ]
  manifest = "meta/storage_user.cml"
}

fuchsia_component("storage_realm") {
  manifest = "meta/storage_realm.cml"
}

fuchsia_component("storage_realm_coll") {
  deps = [ ":storage_realm_coll_bin" ]
  manifest = "meta/storage_realm_coll.cml"
}

fuchsia_unittest_package("storage_integration_test") {
  manifest = "meta/storage_integration_test.cmx"
  deps = [
    ":memfs",
    ":storage_integration_test_bin",
    ":storage_realm",
    ":storage_realm_coll",
    ":storage_user",
  ]
}