src/devices/bin/driver_host/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/assembly/bootfs_files_for_assembly.gni")

group("tests") {
  testonly = true
  deps = [ "tests" ]
}

executable("driver_host") {
  sources = [ "main.cc" ]

  deps = [
    ":common",
    ":driver",
    "//sdk/lib/syslog/cpp:backend_fuchsia_compat",
  ]
}

bootfs_files_for_assembly("bootfs") {
  deps = [ ":driver_host" ]
}

source_set("simple_binding") {
  sources = [
    "simple_binding.cc",
    "simple_binding.h",
  ]

  deps = [
    "//sdk/lib/fidl",
    "//sdk/lib/fidl/cpp/wire",
    "//sdk/lib/fit",
    "//zircon/system/ulib/async",
  ]
  public_deps = [
    "//sdk/lib/fit",
    "//zircon/system/ulib/zx",
  ]
}

source_set("composite_node_spec_util") {
  sources = [ "composite_node_spec_util.h" ]
  public_deps = [
    "//sdk/fidl/fuchsia.device.manager:fuchsia.device.manager_cpp_wire",
    "//src/lib/ddk",
  ]
}

source_set("common") {
  sources = [
    "api.cc",
    "composite_device.cc",
    "core.cc",
    "device_controller_connection.cc",
    "driver.cc",
    "driver_host.cc",
    "driver_host_context.cc",
    "env.cc",
    "fidl_proxy_device.cc",
    "inspect.cc",
    "proxy_iostate.cc",
    "scheduler_profile.cc",
    "tracing.cc",
    "v2.cc",
    "zx_device.cc",
    "zx_driver.cc",
  ]

  deps = [
    ":composite_node_spec_util",
    ":simple_binding",
    "//sdk/fidl/fuchsia.device.fs:fuchsia.device.fs_cpp_wire",
    "//sdk/fidl/fuchsia.io:fuchsia.io_cpp_wire",
    "//sdk/lib/driver/runtime:driver_runtime_env_cpp",
    "//src/devices/lib/driver:driver_runtime",
    "//src/devices/lib/fidl:devfs_fidl",
  ]

  public_deps = [
    "//sdk/fidl/fuchsia.device:fuchsia.device_cpp_wire",
    "//sdk/fidl/fuchsia.device.manager:fuchsia.device.manager_cpp_wire",
    "//sdk/fidl/fuchsia.driver.framework:fuchsia.driver.framework_cpp_wire",
    "//sdk/fidl/fuchsia.scheduler:fuchsia.scheduler_cpp_wire",
    "//sdk/lib/driver/component/cpp:cpp",
    "//sdk/lib/driver/runtime:driver_runtime_cpp",
    "//sdk/lib/driver/runtime:driver_runtime_env",
    "//sdk/lib/driver/runtime:driver_runtime_env_cpp",
    "//sdk/lib/fdio",
    "//sdk/lib/fit-promise",
    "//src/devices/bin/driver_host2:driver",
    "//src/devices/lib/log",
    "//src/lib/ddk",
    "//zircon/system/ulib/async-default",

    # TODO(fxb/38132): Migrate to the new bind rules and delete the below
    "//sdk/lib/component/incoming/cpp",
    "//sdk/lib/component/outgoing/cpp",
    "//sdk/lib/fidl",
    "//src/lib/ddk:ddk-deprecated-binding-headers",
    "//src/lib/ddktl",
    "//src/lib/storage/vfs/cpp",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/inspect",
    "//zircon/system/ulib/sync",
    "//zircon/system/ulib/sync:sync-cpp",
    "//zircon/system/ulib/trace",
    "//zircon/system/ulib/trace-provider",
    "//zircon/system/ulib/zircon-internal",
    "//zircon/system/ulib/zx",
  ]

  configs += [ "//build/config:all_source" ]
}

shared_library("driver") {
  sources = []
  deps = [ ":common" ]
}