# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/fidl/fidl.gni")
import("//build/test.gni")
import("//src/sys/build/fuchsia_unittest_package.gni")

test("fidl-utils") {
  output_name = "fidl-utils-test"
  if (is_fuchsia) {
    configs += [ "//build/unification/config:zircon-migrated" ]
  }
  if (is_fuchsia) {
    fdio_config = [ "//build/config/fuchsia:fdio_config" ]
    if (configs + fdio_config - fdio_config != configs) {
      configs -= fdio_config
    }
  }
  sources = [ "binding_tests.cc" ]
  deps = [
    ":fidl.test.fidlutils_c",
    "//sdk/lib/fdio",
    "//zircon/public/lib/zxtest",
    "//zircon/system/ulib/fidl-utils",
  ]
}

fidl("fidl.test.fidlutils") {
  visibility = [ ":*" ]
  sources = [ "binding_tests.fidl" ]
}

fuchsia_unittest_package("fidl-utils-test-pkg") {
  package_name = "fidl-utils-test"
  deps = [ ":fidl-utils" ]
}

group("tests") {
  testonly = true
  deps = [ ":fidl-utils-test-pkg" ]
}