src/developer/memory/metrics/tests/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/test/test_package.gni")

group("tests") {
  testonly = true
  deps = [ ":memory_metrics_tests" ]
}

source_set("utils") {
  testonly = true
  sources = [
    "test_utils.cc",
    "test_utils.h",
  ]
  deps = [
    "//garnet/public/lib/gtest",
    "//src/developer/memory/metrics",
    "//src/lib/fxl",
    "//zircon/public/lib/zx",
  ]

  # TODO(fxbug.dev/58162): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-conversion" ]
}

executable("memory_metrics_unittests") {
  testonly = true
  output_name = "memory_metrics_unittests"
  sources = [
    "capture_unittest.cc",
    "digest_unittest.cc",
    "printer_unittest.cc",
    "summary_unittest.cc",
    "watcher_unittest.cc",
  ]

  deps = [
    ":utils",
    "//garnet/public/lib/gtest",
    "//sdk/lib/sys/cpp/testing:unit",
    "//src/developer/memory/metrics",
    "//src/lib/fxl/test:gtest_main",
    "//third_party/rapidjson",
  ]

  # TODO(fxbug.dev/58160): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-reorder-init-list" ]

  # TODO(fxbug.dev/58162): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-conversion" ]
}

test_package("memory_metrics_tests") {
  deps = [
    ":memory_metrics_systemtests",
    ":memory_metrics_unittests",
  ]

  tests = [
    {
      name = "memory_metrics_unittests"
    },
    {
      name = "memory_metrics_systemtests"
    },
  ]
}

executable("memory_metrics_systemtests") {
  testonly = true
  output_name = "memory_metrics_systemtests"
  sources = [ "capture_systemtest.cc" ]

  deps = [
    ":utils",
    "//garnet/public/lib/gtest",
    "//sdk/lib/sys/cpp/testing:unit",
    "//src/developer/memory/metrics",
    "//src/lib/fxl/test:gtest_main",
  ]
}