src/modular/bin/sessionmgr/storage/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/testing/environments.gni")
import("//src/modular/build/tests_package.gni")

hermetic_tests_package("storage_unittests") {
  deps = [
    ":encode_module_path_unittest",
    ":session_storage_unittest",
    ":story_storage_unittest",
    ":watcher_list_unittest",
  ]
  environments = basic_envs
}

group("storage") {
  public_deps = [
    ":session_storage",
    ":story_storage",
  ]
}

source_set("encode_module_path") {
  sources = [
    "encode_module_path.cc",
    "encode_module_path.h",
  ]

  deps = [
    "//sdk/lib/fidl/cpp",
    "//sdk/lib/syslog/cpp",
    "//src/lib/fxl",
    "//src/modular/lib/string_escape",
  ]

  public_deps = [
    "//sdk/fidl/fuchsia.modular",
    "//sdk/fidl/fuchsia.modular.internal",
  ]
}

executable("encode_module_path_unittest") {
  testonly = true

  sources = [ "encode_module_path_unittest.cc" ]

  deps = [
    ":encode_module_path",
    "//src/lib/fsl",
    "//src/lib/fxl/test:gtest_main",
    "//third_party/googletest:gtest",
  ]
}

source_set("session_storage") {
  sources = [
    "session_storage.cc",
    "session_storage.h",
  ]

  deps = [
    ":watcher_list",
    "//src/modular/bin/sessionmgr/storage:encode_module_path",
    "//src/modular/lib/fidl:clone",
  ]

  public_deps = [
    ":story_storage",
    "//sdk/fidl/fuchsia.modular",
    "//sdk/fidl/fuchsia.modular.internal",
    "//src/modular/bin/sessionmgr:annotations",
    "//src/modular/lib/async/cpp:future",
  ]
}

executable("session_storage_unittest") {
  testonly = true

  sources = [ "session_storage_unittest.cc" ]

  deps = [
    ":session_storage",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/loop_fixture",
    "//src/modular/bin/sessionmgr/testing:annotations_matchers",
    "//src/modular/lib/async/cpp:future",
    "//src/modular/lib/fidl:array_to_string",
    "//third_party/googletest:gmock",
    "//third_party/googletest:gtest",
    "//zircon/system/public",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
  ]
}

source_set("story_storage") {
  sources = [
    "story_storage.cc",
    "story_storage.h",
  ]

  deps = [
    ":watcher_list",
    "//sdk/fidl/fuchsia.modular",
    "//src/lib/fsl",
    "//src/modular/bin/sessionmgr/storage:encode_module_path",
    "//src/modular/lib/async/cpp:future",
    "//src/modular/lib/fidl:clone",
  ]
  public_deps = [ "//sdk/fidl/fuchsia.modular.internal" ]
}

source_set("watcher_list") {
  sources = [ "watcher_list.h" ]

  public_deps = [
    "//src/lib/fxl",
    "//zircon/public/lib/fit",
  ]
}

executable("story_storage_unittest") {
  testonly = true

  sources = [ "story_storage_unittest.cc" ]

  deps = [
    ":story_storage",
    "//src/lib/fsl",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/loop_fixture",
    "//src/modular/lib/async/cpp:future",
    "//third_party/googletest:gtest",
    "//zircon/system/public",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
  ]
}

executable("watcher_list_unittest") {
  testonly = true

  sources = [ "watcher_list_unittest.cc" ]

  deps = [
    ":watcher_list",
    "//src/lib/fxl/test:gtest_main",
    "//third_party/googletest:gtest",
    "//zircon/public/lib/fit",
  ]
}