zircon/system/dev/display/mt8167s-display/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

driver("mt8167s-display") {
  sources = [
    "aal.cpp",
    "ccorr.cpp",
    "color.cpp",
    "disp-rdma.cpp",
    "dither.cpp",
    "gamma.cpp",
    "lcd.cpp",
    "mt-dsi-host.cpp",
    "mt-sysconfig.cpp",
    "mt8167s-display.cpp",
    "ovl.cpp",
  ]
  deps = [
    ":common",
    "$zx/system/dev/lib/mmio",
  ]
}

source_set("common") {
  visibility = [ ":*" ]
  sources = []
  public_deps = [
    "$zx/system/banjo/ddk.protocol.composite",
    "$zx/system/banjo/ddk.protocol.display.controller",
    "$zx/system/banjo/ddk.protocol.dsiimpl",
    "$zx/system/banjo/ddk.protocol.platform.device",
    "$zx/system/banjo/ddk.protocol.power",
    "$zx/system/banjo/ddk.protocol.sysmem",
    "$zx/system/fidl/fuchsia-sysmem:c",
    "$zx/system/ulib/ddk",
    "$zx/system/ulib/ddktl",
    "$zx/system/ulib/fbl",
    "$zx/system/ulib/hwreg",
    "$zx/system/ulib/image-format",
    "$zx/system/ulib/mipi-dsi",
    "$zx/system/ulib/zircon",
    "$zx/system/ulib/zx",
  ]
}

group("tests") {
  testonly = true
  deps = [
    ":dsi-host",
  ]
}

test("dsi-host") {
  sources = [
    "aal.cpp",
    "ccorr.cpp",
    "color.cpp",
    "disp-rdma.cpp",
    "dither.cpp",
    "gamma.cpp",
    "lcd.cpp",
    "mt-dsi-host.cpp",
    "mt-sysconfig.cpp",
    "mt8167s-display-test.cpp",
    "mt8167s-display.cpp",
    "ovl.cpp",
  ]
  deps = [
    ":common",
    "$zx/system/dev/lib/fake-bti",
    "$zx/system/dev/lib/mock-mmio-reg",
    "$zx/system/ulib/driver",
    "$zx/system/ulib/zxtest",
  ]
}