src/developer/development-bridge/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/host.gni")
import("./build/ffx.gni")

group("development-bridge") {
  testonly = true

  public_deps = [
    ":ffx",
    ":tests",
  ]
}

if (host_toolchain == current_toolchain) {
  ffx("ffx") {
    version = "0.1.0"
    edition = "2018"
    with_unit_tests = true

    plugin_deps = [
      "//src/developer/development-bridge/device:ffx_powerctl",
      "//src/developer/development-bridge/discovery:ffx_knock",
      "//src/developer/development-bridge/discovery:ffx_select",
      "//src/developer/development-bridge/plugins/config:ffx_config_plugin",
      "//src/developer/development-bridge/plugins/echo:ffx_echo",
      "//src/developer/development-bridge/plugins/test:ffx_test",
      "//src/developer/development-bridge/run-component:ffx_run_component",
    ]

    deps = [
      "config:lib",
      "core:lib",
      "daemon:lib",
      "//sdk/fidl/fuchsia.developer.bridge:fuchsia.developer.bridge-rustc",
      "//sdk/fidl/fuchsia.developer.remotecontrol:fuchsia.developer.remotecontrol-rustc",
      "//sdk/fidl/fuchsia.diagnostics:fuchsia.diagnostics-rustc",
      "//sdk/fidl/fuchsia.net:fuchsia.net-rustc",
      "//sdk/fidl/fuchsia.overnet:fuchsia.overnet-rustc",
      "//sdk/fidl/fuchsia.overnet.protocol:fuchsia.overnet.protocol-rustc",
      "//src/connectivity/overnet/lib/hoist",
      "//src/lib/fidl/rust/fidl",
      "//third_party/rust_crates:anyhow",
      "//third_party/rust_crates:argh",
      "//third_party/rust_crates:chrono",
      "//third_party/rust_crates:futures",
      "//third_party/rust_crates:log",
      "//third_party/rust_crates:simplelog",
    ]
  }
}

install_host_tools("host") {
  deps = [ ":ffx_bin($host_toolchain)" ]
  outputs = [ "ffx" ]
}

group("ffx") {
  deps = [
    ":ffx_bin($host_toolchain)",
    ":host",
    "daemon:lib($host_toolchain)",
  ]
}

group("runtime") {
  deps = [
    # The tool
    ":host",

    # Target-side dependencies
    "//src/developer/remote-control:runtime",
  ]
}

group("tests") {
  testonly = true
  deps = [
    ":ffx_tests($host_toolchain)",
    "core:tests",
    "daemon:tests",
  ]
}