zircon/kernel/image/user/BUILD.gn

# Copyright 2026 The Fuchsia Authors
#
# Use of this source code is governed by a MIT-style
# license that can be found in the LICENSE file or at
# https://opensource.org/licenses/MIT

import("//build/zbi/kernel_cmdline.gni")
import("//zircon/kernel/kernel_image.gni")
import("//zircon/kernel/kernel_package.gni")

kernel_package("zircon") {
  visibility = [ ":*" ]
  deps = [
    "..:common-package-items",
    "//zircon/kernel/bin:vmzircon(//zircon/kernel/switch/set/lk_debug_level_0:kernel_${current_cpu}.lk_debug_level_0)",
  ]
}

kernel_cmdline("cmdline") {
  visibility = [ ":*" ]
  args = [
    # TODO(https://fxbug.dev/509616048): Currently these settings are overrode
    # in Assembly by the same values. We keep things in sync with IFTTT until
    # we can eventually make this the source of truth.
    #
    # LINT.IfChange
    "kernel.enable-debugging-syscalls=false",
    "kernel.enable-serial-syscalls=false",

    # LINT.ThenChange(//bundles/assembly/BUILD.gn)
  ]
}

kernel_image("user") {
  output_name = "kernel.user"
  deps = [
    ":cmdline",
    ":zircon",
    "//zircon/kernel/phys:physboot",
  ]
}

group("user.test-data-deps") {
  testonly = true
  deps = [ "//zircon/kernel/image:common-test-boot-options" ]
}