zircon/kernel/image/eng/BUILD.gn

# Copyright 2026 The Fuchsia Authors
#
# Use of this source code is governed by a MIT-style
# license that can be found in the LICENSE file or at
# https://opensource.org/licenses/MIT

import("//build/zbi/kernel_cmdline.gni")
import("//zircon/kernel/kernel_image.gni")
import("//zircon/kernel/kernel_package.gni")

kernel_package("zircon") {
  testonly = true
  visibility = [ ":*" ]
  deps = [
    "..:common-package-items",
    "//zircon/kernel/bin:vmzircon.with-tests(//zircon/kernel/switch/set/lk_debug_level_2:kernel_${current_cpu}.lk_debug_level_2)",
  ]
}

kernel_cmdline("cmdline") {
  testonly = true

  args = [
    # TODO(https://fxbug.dev/509616048): Currently these settings are overrode
    # in Assembly by the same values. We keep things in sync with IFTTT until
    # we can eventually make this the source of truth.
    #
    # LINT.IfChange
    "kernel.enable-debugging-syscalls=true",
    "kernel.enable-serial-syscalls=true",

    # LINT.ThenChange(//bundles/assembly/BUILD.gn)
  ]
}

kernel_image("eng") {
  testonly = true
  output_name = "kernel.eng"
  deps = [
    ":cmdline",
    ":zircon",
    "//zircon/kernel/phys:physboot",
  ]
}

kernel_cmdline("test-boot-options") {
  visibility = [ ":*" ]
  testonly = true
  args = [
    "kernel.pmm.alloc-random-should-wait=true",
    "kernel.compression.random-debug-compress=true",
  ]
}

group("eng.test-data-deps") {
  testonly = true
  deps = [
    ":test-boot-options",
    "//zircon/kernel/image:common-test-boot-options",
  ]
}