src/developer/ffx/plugins/target/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//src/developer/ffx/build/ffx_plugin.gni")
import("//src/developer/ffx/build/ffx_tool.gni")

if (is_host) {
  ffx_plugin("ffx_target") {
    sdk_category = "not-yet-specified"
    version = "0.1.0"
    edition = "2024"
    plugin_deps = [
      "add:ffx_target_add",
      "bootloader:ffx_bootloader",
      "clear-preferred-ssh-address:ffx_target_clear_preferred_ssh_address",
      "default:ffx_target_default",
      "discover:ffx_target_discover",
      "echo:ffx_target_echo",
      "fastboot:ffx_fastboot_tool",
      "flash:ffx_flash",
      "get-time:ffx_target_get_time",
      "list:ffx_list",
      "log-message:ffx_target_log_message",
      "off:ffx_off",
      "package:ffx_target_package",
      "reboot:ffx_reboot",
      "remove:ffx_target_remove",
      "repository:ffx_target_repository",
      "screenshot:ffx_target_screenshot",
      "set-preferred-ssh-address:ffx_target_set_preferred_ssh_address",
      "show:ffx_target_show",
      "snapshot:ffx_snapshot",
      "ssh:ffx_target_ssh",
      "status:ffx_target_status",
      "update:ffx_update",
      "wait:ffx_wait",
    ]

    args_sources = [ "src/args.rs" ]
    args_deps = [
      "//src/developer/ffx/core:lib",
      "//third_party/rust_crates:argh",
    ]
  }

  ffx_tool("ffx_target_tool") {
    edition = "2024"
    output_name = "ffx-target"
    deps = [
      ":ffx_target_suite",
      "//src/lib/fuchsia-async",
    ]
    sources = [ "src/main.rs" ]
  }

  group("tests") {
    testonly = true
    deps = [
      "default:tests",
      "log-message:tests",
    ]
  }

  group("host_tests") {
    testonly = true
    deps = [
      "list:tests",
      "package:host_tests",
      "ssh:host_tests",
    ]
  }
}

if (is_fuchsia) {
  group("package_deps_for_host_tests") {
    testonly = true
    deps = [ "package:package_deps_for_host_tests" ]
  }
}