src/connectivity/bluetooth/hci/vendor/broadcom/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bazel/export_fuchsia_package_to_bazel.gni")
import("//build/bind/bind.gni")
import("//build/cipd.gni")
import("//build/components.gni")
import("//build/drivers.gni")
import("//build/test.gni")
import("//build/testing/cc_test_executable.gni")
import("//build_overrides/pigweed.gni")
import("//tools/power_config/build/config.gni")
import("$dir_pigweed/third_party/emboss/build_defs.gni")

fuchsia_driver_dml("broadcom-dml") {
  dml = "meta/broadcom.dml"
  driver_name = "broadcom"
}

driver_bind_rules("bcm_hci_bind") {
  dml_label = ":broadcom-dml"
  bind_output = "bt-hci-broadcom.bindbc"
  tests = "meta/bind_tests.json"
  deps = [ "//src/devices/bind/fuchsia" ]
}

fuchsia_component_manifest("bt-hci-broadcom-manifest") {
  component_name = "bt-hci-broadcom"
  manifest = "meta/broadcom.cml"
}

fuchsia_structured_config_cpp_elf_lib("bt-hci-broadcom-config") {
  cm_label = ":bt-hci-broadcom-manifest"
}

source_set("common") {
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]

  sources = [
    "bt_hci_broadcom.cc",
    "bt_hci_broadcom.h",
  ]

  deps = [
    ":bcm_hci_bind",
    ":emboss",
    "//sdk/fidl/fuchsia.boot.metadata:fuchsia.boot.metadata_cpp",
    "//sdk/lib/async-default",
    "//sdk/lib/async-loop:async-loop-cpp",
    "//sdk/lib/async-loop:async-loop-default",
    "//sdk/lib/driver/metadata/cpp",
    "//sdk/lib/fidl",
    "//src/devices/lib/driver:driver_runtime",
    "//zircon/system/ulib/sync",
    "//zircon/system/ulib/sync:sync-cpp",
  ]

  public_deps = [
    ":bt-hci-broadcom-config",
    "//sdk/fidl/fuchsia.driver.framework:fuchsia.driver.framework_cpp",
    "//sdk/fidl/fuchsia.hardware.bluetooth:fuchsia.hardware.bluetooth_cpp",
    "//sdk/fidl/fuchsia.hardware.power:fuchsia.hardware.power_cpp",
    "//sdk/fidl/fuchsia.hardware.serialimpl:fuchsia.hardware.serialimpl_cpp",
    "//sdk/lib/driver/component/cpp",
    "//sdk/lib/driver/logging/cpp",
    "//sdk/lib/driver/power/cpp",
    "//src/lib/ddk",
    "//src/lib/ddktl",
    "//tools/power_config/lib/cpp",
  ]

  # TODO(https://fxbug.dev/42136089): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-conversion" ]
}

fuchsia_cc_driver("bt-hci-broadcom-driver") {
  output_name = "bt-hci-broadcom"
  deps = [ ":common" ]
}

fuchsia_driver_component("bt-hci-broadcom") {
  component_name = "bt-hci-broadcom"
  deps = [ ":bt-hci-broadcom-driver" ]
  info = "meta/bt-hci-broadcom-info.json"
  manifest = "meta/broadcom.cml"
}

power_config("broadcom-power-config") {
  output_name = "broadcom_power.fidl"
  value_file = "meta/broadcom_power.json5"
}

# This is the firmware for VIM3 board only
resource("broadcom-firmware-vim3") {
  sources = [
    "//prebuilt/connectivity/bluetooth/firmware/broadcom/vim3/BCM4359C0.hcd",
  ]
  outputs = [ "lib/firmware/{{source_file_part}}" ]
}

resource("broadcom-firmware-sorrel") {
  sources = [
    "//prebuilt/connectivity/bluetooth/firmware/broadcom/sorrel/BCM4381A1.hcd",
  ]
  outputs = [ "lib/firmware/{{source_file_part}}" ]
}

# This package is only referenced by vim3.gni for now.
fuchsia_driver_package("broadcom") {
  driver_components = [ ":bt-hci-broadcom" ]

  deps = [ ":broadcom-power-config" ]

  if (internal_access) {
    deps += [ ":broadcom-firmware-vim3" ]
  }
}

# This package is only referenced by moonflower/BUILD.gn for now.
fuchsia_driver_package("broadcom-sorrel") {
  export_to_bazel = true
  driver_components = [ ":bt-hci-broadcom" ]

  deps = [ ":broadcom-power-config" ]

  if (internal_access) {
    deps += [ ":broadcom-firmware-sorrel" ]
  }
}

cc_test_executable("tests_executable") {
  testonly = true

  output_name = "bt-hci-broadcom-tests"

  sources = [ "bt_hci_broadcom_unittest.cc" ]

  deps = [
    ":common",
    ":emboss",
    "//sdk/fidl/fuchsia.boot.metadata:fuchsia.boot.metadata_cpp",
    "//sdk/lib/async_patterns/testing/cpp",
    "//sdk/lib/component/outgoing/cpp",
    "//sdk/lib/driver/metadata/cpp",
    "//sdk/lib/driver/testing/cpp",
    "//sdk/lib/fdio",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/loop_fixture",
    "//src/storage/lib/vfs/cpp",
    "//third_party/googletest:gtest",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/fzl",
    "//zircon/system/ulib/sync",
    "//zircon/system/ulib/sync:sync-cpp",
    "//zircon/system/ulib/zircon-internal",
    "//zircon/system/ulib/zx",
  ]
}

fuchsia_unittest_package("bt-hci-broadcom-tests") {
  deps = [
    ":broadcom-power-config",
    ":tests_executable",
  ]
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
}

group("tests") {
  testonly = true
  deps = [
    ":bcm_hci_bind_test",
    ":bt-hci-broadcom-tests",
  ]
}

emboss_cc_library("emboss") {
  # public_configs = [ ":emboss_include_path" ]
  source = "packets.emb"
  imports = [ "$dir_pw_bluetooth/public/pw_bluetooth/hci_common.emb" ]
  import_dirs = [ "$dir_pw_bluetooth/public" ]
  public_deps = [
    "$dir_pw_bluetooth:emboss_hci_common",
    "$dir_pw_bluetooth:emboss_hci_events",
  ]
}