build/info/info.gni

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/board.gni")

declare_args() {
  # LINT.IfChange
  # Product configuration of the current build
  build_info_product = ""

  # Board configuration of the current build
  build_info_board = board_name

  # Logical version of the current build. If not set, defaults to the timestamp
  # of the most recent update.
  build_info_version = ""

  # Truncate the date in the build_info to midnight UTC, and replace the commit
  # hash with one that's synthesized from that date.
  # This is not meant to be used outside this directory. It is only in this .gni
  # file so that //build/bazel:gn_build_variables_for_bazel can access it.
  truncate_build_info_commit_date = false

  # LINT.ThenChange(//build/bazel/BUILD.gn)
}

# Alias core_size_limits to core_with_minfs
#
# This is temporary to ease the removal of core_size_limits builders
# while we transition to the new product bundle model
if (build_info_product == "core_size_limits") {
  build_info_product = "core_with_minfs"
}

build_info_files = {
  product = "$root_build_dir/product.txt"
  board = "$root_build_dir/board.txt"
  version = "$root_build_dir/version.txt"

  # LINT.IfChange
  jiri_snapshot = "//.jiri_root/update_history/latest"

  # LINT.ThenChange(//build/bazel/scripts/workspace_utils.py)

  latest_commit_hash = "$root_build_dir/latest-commit-hash.txt"
  latest_commit_date = "$root_build_dir/latest-commit-date.txt"
  minimum_utc_stamp = "$root_build_dir/minimum-utc-stamp.txt"
}

default_product_build_info = {
  name = build_info_product
  version = "version.txt"
  jiri_snapshot = "../../.jiri_root/update_history/latest"
  latest_commit_date = "latest-commit-date.txt"
}