src/ui/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//src/sys/core/build/core_shard.gni")

group("ui") {
  testonly = true
  deps = [
    "a11y",
    "bin",
    "examples",
    "input",
    "scenic",
    "tools",
    "wayland",
  ]
}

group("tests") {
  testonly = true

  deps = [
    "a11y:tests",
    "backlight:tests",
    "bin:tests",
    "examples:tests",
    "input:tests",
    "lib:tests",
    "light:tests",
    "scenic:tests",
    "testing:tests",
    "tests",
    "tools:tests",
    "wayland:tests",
  ]
}

core_shard("ui_core_shard") {
  shard_file = "meta/ui.core_shard.cml"
}

core_shard("ui_minimal_core_shard") {
  shard_file = "meta/ui_minimal.core_shard.cml"
}

fuchsia_component("ui_component") {
  component_name = "ui"
  manifest = "meta/ui.cml"
}

fuchsia_component("ui_minimal_component") {
  component_name = "ui_minimal"
  manifest = "meta/ui_minimal.cml"
}

fuchsia_package("ui_package") {
  package_name = "ui"

  deps = [ ":ui_component" ]
}

fuchsia_package("ui_minimal_package") {
  package_name = "ui"

  deps = [ ":ui_minimal_component" ]
}

group("ui_packages_base") {
  deps = [
    "a11y",
    "bin/scene_manager",
    "bin/text:text_manager",
    "bin/virtual_keyboard_manager",
    "scenic",
  ]
}

group("ui_packages") {
  deps = [
    ":ui_package",
    ":ui_packages_base",
  ]
}

group("ui_minimal_packages") {
  deps = [
    ":ui_minimal_package",
    ":ui_packages_base",
  ]
}