src/devices/usb/drivers/usb-hub-rewrite/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/config/fuchsia/rules.gni")
import("//build/test.gni")
import("//build/test/test_package.gni")
import("//src/sys/build/components.gni")

bind_rules("bind") {
  rules = "usb-hub-rewrite.bind"
  output = "usb_hub_rewrite_bind.h"
  deps = [ "//src/devices/bind/fuchsia.usb" ]
}

driver_module("usb-hub-rewrite") {
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [
    "//build/config/fuchsia:static_cpp_standard_library",
    "//build/unification/config:zircon-migrated",
  ]
  sources = [ "usb-hub.cc" ]
  deps = [
    ":bind",
    "//sdk/banjo/ddk.protocol.usb",
    "//sdk/banjo/ddk.protocol.usb.bus",
    "//sdk/banjo/ddk.protocol.usb.composite",
    "//sdk/banjo/ddk.protocol.usb.hub",
    "//sdk/banjo/ddk.protocol.usb.request",
    "//src/devices/lib/driver",
    "//src/devices/lib/synchronous-executor",
    "//src/devices/usb/lib/usb",
    "//src/lib/ddk",
    "//zircon/public/lib/async",
    "//zircon/public/lib/async-cpp",
    "//zircon/public/lib/sync",
    "//zircon/public/lib/zxc",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/inspect",
  ]
}

test("usb-hub-test") {
  configs += [ "//build/unification/config:zircon-migrated" ]
  sources = [
    "usb-hub-test.cc",
    "usb-hub.cc",
  ]
  defines = [ "UNITTEST" ]
  deps = [
    ":bind",
    "//sdk/banjo/ddk.protocol.usb",
    "//sdk/banjo/ddk.protocol.usb.bus",
    "//sdk/banjo/ddk.protocol.usb.composite",
    "//sdk/banjo/ddk.protocol.usb.hub",
    "//sdk/banjo/ddk.protocol.usb.request",
    "//sdk/lib/fdio",
    "//src/devices/lib/synchronous-executor",
    "//src/devices/testing/fake-bti",
    "//src/devices/testing/fake_ddk",
    "//src/devices/usb/lib/usb",
    "//zircon/public/lib/async",
    "//zircon/public/lib/async-cpp",
    "//zircon/public/lib/fit",
    "//zircon/public/lib/zxc",
    "//zircon/public/lib/zxtest",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/inspect",
  ]
}

fuchsia_unittest_package("usb-hub-package") {
  executable_path = "test/usb-hub-test"
  deps = [ ":usb-hub-test" ]
}

group("tests") {
  testonly = true
  deps = [ ":usb-hub-package" ]
}