src/lib/test_executor/rust/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/rust/rustc_library.gni")
import("//build/test/test_package.gni")

rustc_library("test_executor") {
  with_unit_tests = true
  edition = "2018"

  deps = [
    "//sdk/fidl/fuchsia.sys:fuchsia.sys-rustc",
    "//sdk/fidl/fuchsia.test:fuchsia.test-rustc",
    "//src/connectivity/overnet/lib/hoist",
    "//src/lib/fidl/rust/fidl",
    "//src/sys/test_manager/fidl:test_manager-rustc",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:log",
    "//third_party/rust_crates:thiserror",
  ]
  if (is_fuchsia) {
    deps += [ "//src/lib/fuchsia-component" ]
  }
}

group("tests") {
  testonly = true
  deps = [ ":test_executor_unittests" ]
}

unittest_package("test_executor_unittests") {
  deps = [ ":test_executor_test" ]

  tests = [
    {
      name = "test_executor_lib_test"
      dest = "test_executor_lib_test"
      environments = basic_envs
    },
  ]
}