src/modular/bin/module_resolver/BUILD.gn

# Copyright 2017 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/package.gni")
import("//build/testing/environments.gni")
import("//src/modular/build/executable_package.gni")
import("//src/modular/build/tests_package.gni")

executable_package("module_resolver") {
  meta = [
    {
      path = "meta/module_resolver.cmx"
      dest = "module_resolver.cmx"
    },
  ]

  sources = [
    "module_resolver_main.cc",
  ]

  deps = [
    ":local_module_resolver",
    "//sdk/fidl/fuchsia.modular",
    "//sdk/fidl/fuchsia.net.oldhttp",
    "//sdk/lib/sys/cpp",
    "//src/lib/fxl",
    "//src/modular/lib/app_driver/cpp:app_driver",
    "//src/modular/lib/entity/cpp:json",
    "//src/modular/lib/module_manifest_source:module_package_source",
    "//zircon/public/lib/async-loop-cpp",
    "//zircon/public/lib/async-loop-default",
  ]
}

hermetic_tests_package("module_resolver_unittests") {
  deps = [
    ":local_module_resolver_unittest",
  ]
  environments = basic_envs
}

source_set("local_module_resolver") {
  sources = [
    "local_module_resolver.cc",
    "local_module_resolver.h",
  ]

  deps = [
    "//sdk/fidl/fuchsia.modular",
    "//src/lib/fxl",
    "//src/modular/lib/async/cpp:operation",
    "//src/modular/lib/entity/cpp:json",
    "//src/modular/lib/fidl:clone",
    "//src/modular/lib/module_manifest_source",
  ]
}

executable("local_module_resolver_unittest") {
  testonly = true

  sources = [
    "local_module_resolver_unittest.cc",
  ]

  deps = [
    ":local_module_resolver",
    "//garnet/public/lib/gtest",
    "//src/lib/fsl",
    "//src/lib/fxl",
    "//src/lib/fxl/test:gtest_main",
    "//src/modular/lib/entity/cpp:json",
    "//src/modular/lib/fidl:clone",
    "//src/modular/lib/testing:entity_resolver_fake",
  ]
}