secondary/third_party/llvm/lib/IR/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("../../utils/TableGen/tablegen.gni")

tablegen("attributes") {
  source = "../../include/llvm/IR/Attributes.td"
  output = "$target_gen_dir/llvm/IR/Attributes.gen"
  args = [ "-gen-attrs" ]
}

tablegen("attributes_compat_func") {
  source = "AttributesCompatFunc.td"
  output = "$target_gen_dir/AttributesCompatFunc.inc"
  args = [ "-gen-attrs" ]
}

tablegen("intrinsics") {
  source = "../../include/llvm/IR/Intrinsics.td"
  output = "$target_gen_dir/llvm/IR/Intrinsics.gen"
  args = [ "-gen-intrinsic" ]
}

config("includes") {
  include_dirs = [ target_gen_dir ]
}

static_library("IR") {
  sources = [
    "AsmWriter.cpp",
    "Attributes.cpp",
    "AutoUpgrade.cpp",
    "BasicBlock.cpp",
    "Comdat.cpp",
    "ConstantFold.cpp",
    "ConstantRange.cpp",
    "Constants.cpp",
    "Core.cpp",
    "DIBuilder.cpp",
    "DataLayout.cpp",
    "DebugInfo.cpp",
    "DebugInfoMetadata.cpp",
    "DebugLoc.cpp",
    "DiagnosticHandler.cpp",
    "DiagnosticInfo.cpp",
    "DiagnosticPrinter.cpp",
    "Dominators.cpp",
    "Function.cpp",
    "GVMaterializer.cpp",
    "Globals.cpp",
    "IRBuilder.cpp",
    "IRPrintingPasses.cpp",
    "InlineAsm.cpp",
    "Instruction.cpp",
    "Instructions.cpp",
    "IntrinsicInst.cpp",
    "LLVMContext.cpp",
    "LLVMContextImpl.cpp",
    "LegacyPassManager.cpp",
    "MDBuilder.cpp",
    "Mangler.cpp",
    "Metadata.cpp",
    "Module.cpp",
    "ModuleSummaryIndex.cpp",
    "Operator.cpp",
    "OptBisect.cpp",
    "Pass.cpp",
    "PassManager.cpp",
    "PassRegistry.cpp",
    "ProfileSummary.cpp",
    "SafepointIRVerifier.cpp",
    "Statepoint.cpp",
    "Type.cpp",
    "TypeFinder.cpp",
    "Use.cpp",
    "User.cpp",
    "Value.cpp",
    "ValueSymbolTable.cpp",
    "Verifier.cpp",
  ]

  public_configs = [ ":includes" ]

  public_deps = [
    ":attributes",
    ":attributes_compat_func",
    ":intrinsics",
    "../Support",
  ]
}